@ echo off

if not "%1"=="" goto los
echo pfb-sfp [-] fontname outnam [resolutionx] [resolutiony] [encoding]
echo fontname without .pfb
echo outnam at most 6 characters
echo printer resolution defaults to 300 300
echo encoding vector file (without suffix .enc)
echo    - defaults to fontname.ENC if existing, C:\Adobe\foundry\W.ENC otherwise
echo PSIZES may be set to list of sizes to be generated, defaults to 10 12
echo an additional starting "-" leaves intermediate files
goto end

:los
rem try to make some space in environment (NC problem):
set dumvar=

set del=
if not "%1"=="-" goto mach
set del=rem
shift

:mach
set name=%1
set namo=%2
if "%2"=="" set namo=%1
if "%PSIZES%" == "" set PSIZES=10 12

set resx=300
set resy=300
if not "%3"=="" set resx=%3
if not "%4"=="" set resy=%4
echo generating for resolution %resx% %resy%

set enc=C:\Adobe\foundry\W
if exist %1.enc set enc=%1
if not "%5"=="" set enc=%5

echo StartTypeface > %namo%.mb
echo Resolution %resx% %resy% >> %namo%.mb
echo Orientation Portrait >> %namo%.mb
echo StandardEncoding %enc%.ENC >> %namo%.mb
echo SpecialEncoding  >> %namo%.mb
for %%s in (%PSIZES%) do call C:\Adobe\makemb %namo% %%s
echo EndTypeface >> %namo%.mb

C:\Adobe\foundry\MAKEBIT.EXE -i %namo%.MB %name%.pfb
%del% del %namo%.mb

for %%s in (%PSIZES%) do C:\Adobe\foundry\MAKELJF.EXE -c 9U -s 1 -w 0 -t 182 -o %namo%%%s.SFP %namo%%%s.BIT
rem for %%s in (%PSIZES%) do C:\Adobe\foundry\MAKEPFM.EXE -h 1 -p %%s -e W.ENC -o %namo%%%s.pfm %name%.AFM

%del% del %namo%*.bit

rem %del% pkzip %namo% %namo%*.sfp
rem %del% del %namo%*.sfp

:end